このチュートリアルは武蔵野美術大学通信教育課程授業用に作成したものです。
今回はDFPlayer Miniを使った音楽再生を行います。
ブレッドボード配線図はこちら
arduino pro microの場合、サンプルに使用している10,11pinではなく、8,9pinを使用し、コードを書き換えます。
使用するにはDFPlayerのライブラリをDLします。
「DFRobotDFPlayerMini」のライブラリをインストールして利用してみてください。
ライブラリをインストールした状態でサンプルからGetStartedを開きます
#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"
SoftwareSerial mySoftwareSerial(10, 11); // RX, TX pro microの場合は変更
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);
////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////
void setup()
{
mySoftwareSerial.begin(9600);
Serial.begin(115200);
Serial.println();
Serial.println(F("DFRobot DFPlayer Mini Demo"));
Serial.println(F("Initializing DFPlayer ... (May take 3~5 seconds)"));
if (!myDFPlayer.begin(mySoftwareSerial)) { //Use softwareSerial to communicate with mp3.
Serial.println(F("Unable to begin:"));
Serial.println(F("1.Please recheck the connection!"));
Serial.println(F("2.Please insert the SD card!"));
while(true);
}
Serial.println(F("DFPlayer Mini online."));
myDFPlayer.volume(10); //Set volume value. From 0 to 30
myDFPlayer.play(1); //Play the first mp3
}
////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////
void loop()
{
static unsigned long timer = millis();
if (millis() - timer > 3000) {
timer = millis();
myDFPlayer.next(); //Play next mp3 every 3 second.
}
if (myDFPlayer.available()) {
printDetail(myDFPlayer.readType(), myDFPlayer.read()); //Print the detail message from DFPlayer to handle different errors and states.
}
}
////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////
void printDetail(uint8_t type, int value){
switch (type) {
case TimeOut:
Serial.println(F("Time Out!"));
break;
case WrongStack:
Serial.println(F("Stack Wrong!"));
break;
case DFPlayerCardInserted:
Serial.println(F("Card Inserted!"));
break;
case DFPlayerCardRemoved:
Serial.println(F("Card Removed!"));
break;
case DFPlayerCardOnline:
Serial.println(F("Card Online!"));
break;
case DFPlayerPlayFinished:
Serial.print(F("Number:"));
Serial.print(value);
Serial.println(F(" Play Finished!"));
break;
case DFPlayerError:
Serial.print(F("DFPlayerError:"));
switch (value) {
case Busy:
Serial.println(F("Card not found"));
break;
case Sleeping:
Serial.println(F("Sleeping"));
break;
case SerialWrongStack:
Serial.println(F("Get Wrong Stack"));
break;
case CheckSumNotMatch:
Serial.println(F("Check Sum Not Match"));
break;
case FileIndexOut:
Serial.println(F("File Index Out of Bound"));
break;
case FileMismatch:
Serial.println(F("Cannot Find File"));
break;
case Advertise:
Serial.println(F("In Advertise"));
break;
default:
break;
}
break;
default:
break;
}
}
////////////////////////////////////////////////////////////////////////////////////
一部コメントなどを変更しています。
このプログラムは大きくは4つのブロックに別れています。
１：ライブラリインクルード、変数定義
２：void setup()関数
３：void loop()関数
４：void printDetail(uint8_t type, int value)関数
void printDetail(uint8_t type, int value)関数はDFPlayerの状態を確認するための関数のため、実は無くても動作します。ただ、DFPlayerの動作チェック（エラーがないかなど）のために残しておくことをおすすめします。分かりにくくてつらいという人は削除して構いません。関数を削除した場合は、void loop()関数内の以下のプログラムも削除してください
if (myDFPlayer.available()) {
printDetail(myDFPlayer.readType(), myDFPlayer.read()); //Print the detail message from DFPlayer to handle different errors and states.
}
こちらで先程のvoid printDetail関数を呼び出しているので、関数削除しただけですとエラーになります。
setup関数の中の「if (!myDFPlayer.begin(mySoftwareSerial)) {」の部分はmySoftwareSerialで指定したピンでDFPlayerを開始した時に上手く開始できたか確認用の記述です。ここを外すと接続が確立する前にloop関数に入ってしまうので記述します。（シリアル確認は特になくても良いです。）
また、DFPlayerはソフトウェアシリアルでの動作なので、デバッグ用のシリアル通信は特に必要ないということであれば更にシンプルにすることができます。こうなります。
#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"
SoftwareSerial mySoftwareSerial(10, 11); // RX, TX pro microの場合は変更
DFRobotDFPlayerMini myDFPlayer;
////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////
void setup()
{
mySoftwareSerial.begin(9600);
if (!myDFPlayer.begin(mySoftwareSerial)) { //Use softwareSerial to communicate with mp3.
while(true){
delay(0); // Code to compatible with ESP8266 watch dog.
}
}
myDFPlayer.volume(10); //Set volume value. From 0 to 30
myDFPlayer.play(1); //Play the first mp3
}
////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////
void loop()
{
static unsigned long timer = millis();
if (millis() - timer > 3000) {
timer = millis();
myDFPlayer.next(); //Play next mp3 every 3 second.
}
}
////////////////////////////////////////////////////////////////////////////////////
上記がこのライブラリのコアになります。
void setup()ではDFPlayerとの通信のためにソフトウェアシリアルを開始、ボリュームの設定、SDカードの最初の音声データを再生します。
void loop()では3000ミリ秒（3秒）ごとにmyDFPlayer.next()、つまり次の音源を呼び出しています。このようなプログラム構成になっています。必要な要素を正しく理解し、活用してみてください。指定した音源を再生したい、音量を変えたいなど他の関数もライブラリに用意されています。利用したい場合は「FullFunction」のサンプルを立ち上げ確認してみてください。
